mirror of
https://github.com/nextcloud/desktop.git
synced 2024-10-24 21:35:47 +03:00
7f598b181e
The UndefinedBehaviorSanitizer includes the "vptr" check. This check, however, needs typeinfo for OCC::AccountManager because otherwise its stub for FileManTest leads to undefined references when linking. Adding the -frtti flag to enable run-time typeinfo did not solve the problem. I do not know another solution, so this commit disables the vptr check. Signed-off-by: Stephan Beyer <s-beyer@gmx.net>
37 lines
1.5 KiB
CMake
37 lines
1.5 KiB
CMake
# Enable address sanitizer (gcc/clang only)
|
|
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
|
|
set(SANITIZERS)
|
|
set(SANITIZER_EXTRA_FLAGS " -g")
|
|
|
|
macro(add_sanitizer_option variable flag help)
|
|
option(${variable} "Enable ${help}" OFF)
|
|
if(${variable})
|
|
list(APPEND SANITIZERS ${flag})
|
|
string(REPLACE ";" " " optional_args "${ARGN}")
|
|
if(optional_args)
|
|
string(APPEND SANITIZER_EXTRA_FLAGS " ${optional_args}")
|
|
endif()
|
|
endif()
|
|
mark_as_advanced(${variable})
|
|
endmacro()
|
|
|
|
add_sanitizer_option(SANITIZE_ADDRESS "address"
|
|
"AddressSanitizer (detects memory violations, buffer overflows, memory leaks)")
|
|
add_sanitizer_option(SANITIZE_LEAK "leak"
|
|
"standalone LeakSanitizer (detects memory leaks only)")
|
|
add_sanitizer_option(SANITIZE_MEMORY "memory"
|
|
"MemorySanitizer (detects reads in uninitialized memory)")
|
|
add_sanitizer_option(SANITIZE_UNDEFINED "undefined"
|
|
"UndefinedBehaviorSanitizer (detects undefined behavior)"
|
|
"-fno-sanitize=vptr")
|
|
add_sanitizer_option(SANITIZE_THREAD "thread"
|
|
"ThreadSanitizer (detects data races)")
|
|
|
|
if(SANITIZERS)
|
|
string(REPLACE ";" "," SANITIZER_FLAGS "${SANITIZERS}")
|
|
set(SANITIZER_FLAGS "-fsanitize=${SANITIZER_FLAGS}${SANITIZER_EXTRA_FLAGS}")
|
|
string(APPEND CMAKE_CXX_FLAGS " ${SANITIZER_FLAGS}")
|
|
string(APPEND CMAKE_C_FLAGS " ${SANITIZER_FLAGS}")
|
|
string(APPEND CMAKE_EXE_LINKER_FLAGS " ${SANITIZER_FLAGS}")
|
|
endif()
|
|
endif()
|